@echo off

set SCRIPT_SETTINGS=settings.cmd
set COMPANY_SETTINGS=..\company\settings.cmd

rem default: disabled
set windows_targetrelease=0

echo ####### %0 #######

echo.
echo searching for SCRIPT settings ...
if NOT EXIST %SCRIPT_SETTINGS% (
  echo INFO: config file %SCRIPT_SETTINGS% NOT FOUND
) else (
  echo OK. Loading SCRIPT settings ...
  call %SCRIPT_SETTINGS%
)

echo.
echo searching for COMPANY settings ...
if NOT EXIST %COMPANY_SETTINGS% (
  echo INFO: config file %COMPANY_SETTINGS% NOT FOUND
) else (
  echo OK. Loading COMPANY settings ...
  call %COMPANY_SETTINGS%
)

echo ++++++++++++++++++++++++++++++++++
echo windows_targetrelease=%windows_targetrelease%
echo ++++++++++++++++++++++++++++++++++
echo.

if %windows_targetrelease% == 0 (
  echo WARNING: windows target release NOT set!
) else (

  echo setting windows update target release ...
  reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" ^
    /v TargetReleaseVersion /t REG_DWORD /d 1 /f
  reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" ^
    /v TargetReleaseVersionInfo /t REG_SZ /d %windows_targetrelease% /f

)

echo ####### %0 #######

